/ ============================= /  STATE  / ============================ /
: OSD : ( .R `csynm ) _d
! _d
D : _d

 ( avg Q : 3 3 3 # ! 27 )
 tab2html D `Q
 "C:/CoSy/K/CoSy/math_a.txt" 0: text

/ ============================= /   LOG   / ============================ /
/ ======================== / tue.mar.20030311 / ======================== /
\d
\d .CoSy
tst : { D x }
/ : .r : 0: "/k/stat_k.txt"    / From  http://kx.com/a
/ aggregations  /  atomic across list
avg:{(+/x)%#x}
var:{avg[x*x]-a*a:avg x}
dev:{_sqrt var x}
  
cov:{avg[x*y]-avg[x]*avg y}
cor:{cov[x;y]%dev[x]*dev y}

/ uniform moving window
avgs:{[n;x]x-(-n)_(((n-1)#0n),0.0),x:+\x%n}
vars:{[n;x]avgs[n;x*x]-a*a:avgs[n;x]}
devs:{[n;x]_sqrt vars[n;x]}
covs:{[n;x;y]avgs[n;x*y]-avgs[n;x]*avgs[n;y]}
cors:{[n;x;y]covs[n;x;y]%devs[n;x]*devs[n;y]}

/ autocorrelation
aut:{(+/*':x)%+/x*x-:(+/x)%#x}

/ weighted average
wavg:{(+/x*y)%+/x}/

/ median
med:{.5*+/x(<x)@_.5*-1 0+#x}

/ x random weighted by y
skew:{(+\y%+/y)_binl x _draw 0}

pi : 3.14159265358979323846

/ normal distribution, e.g. nor[10]
nor:{[n] if[n!2;:-1_ _f n+1] ; t: _sqrt -2 * _log * u: 2 -1 # n _draw 0 ; (t * _sin x) , t * _cos x: (2 * pi) * * | u}

  
/ normal cumulative Abramowitz & Stegun 26.2.17 
normal:{_abs(-x>0)+(%_sqrt 2*pi)*(_exp -.5*x*x)*t*.31938153+t*-.356563782+t*1.781477937+t*-1.821255978+1.330274429*t:%1+.2316419*_abs x}
  
normal ? .95 .975 .98 .99 />/ 1.644853 1.959963 2.053748 2.326347
normal ?  .95 .975 .98 .99 .999 />/ 0n 0n 0n 2.326347 3.090252
  

/ great circle nautical miles (68.7 to 69.4 miles per degree)
gcm:{rm:(%m:180*60%pi)*60 _sv;m*_acos(_sin[x]*_sin y)+_cos[x:rm x 0]*_cos[y:rm y 0]*_cos(rm x 1)-rm y 1}
gcm[lax:(33 57;118 24)] jfk:(40 38;73 47)
  
/ \d .k